VA8: Hover Help broken for Sliders - fixed in V8.0.1

[cknittel]

Hi,

Hover Help was changed between VA 7.5 and VA 8.0. As a consequence, hover help for sliders is now broken (Exception: "EwSlider does not understand parentView").

If I add EwSlider to the special cases handled in the new method CwDrawingArea>>#associatedPart, hover help for sliders works fine again:

Code: Select all

associatedPart
   "Private - Answer the part associated with the receiver.
   
   This is a slight hack to get around the fact that the internal structure of some parts is more complicated
   than a single common widget pointing back to the part to which it belongs."

   | w |
   ((w := self userData) isKindOf: EwNotebook)   
      ifTrue: [^w associatedPart ].
   ((w isKindOf: EwIconTree) or: [w isKindOf: EwIconList])
      ifTrue: [^w associatedPart].
   (w isKindOf: EwIconArea)
      ifTrue: [^w associatedPart].
   (w isKindOf: EwTableList)
      ifTrue: [^w associatedPart].

   "=== added by Christoph ==="
   (w isKindOf: EwSlider)
      ifTrue: [^w associatedPart].
   "=== added by Christoph ==="

   ^super associatedPart


Please include this fix in the next VA version.

BTW, couldn't this be done in a slightly less ugly way? Maybe something like

Code: Select all

associatedPart
   | w |
   w := self userData.

   ^w class needsDrawingAreaHoverHelpHack
      ifTrue: [ w associatedPart ]
      ifFalse: [ super associatedPart ].


?

Thanks and best regards,
Christoph

[wembley]

Christoph -

You are correct, the code is very ugly. What this code is attempting to do is determine the actual part associated with a widget. I think there is a much simpler way to do that:

Code: Select all

CwWidget>>#associatedPart
   "Answer the part associated with the receiver.  Most parts wrap a single
    widget that points directly back to the part, but some parts wrap nested
    widgets and recursive dereferencing is needed to find the part from the widget."

   | part |

   part := self userData.
   ^ (part isNil or: [ part isBasicView ])
      ifTrue: [ part ]   
      ifFalse: [ part associatedPart ]

Object>>#isBasicView
   "Answer true if this is a basic view part."

   ^false

All the other implementations of #associatedPart can be removed. Please try this out and let me know if it works for you. Case 41884 opened.

[cknittel]

Hi John,

This works fine for me, thanks a lot! Great solution!

Best regards,
Christoph