VA 7.5 Upgrade Oracle support to v10

[mariocarrera]

Hi!
I read that it is an upgrade Oracle support to v10. I use actuali vast 601 and oracle 10 and I have no probles, I want to know wy I need the new suport?
thanks

Mario

[tc]

Hello,

The Oracle 10 feature of VA Smalltalk provide LOBs (true LOB suppport), and BFile support. It also includes fixes.

For example, the following high level DB code did not work with native Oracle:

Code: Select all

| connection newRow table oc |
(AbtDatabaseConnectionSpec forDbmClass: AbtOracle10DatabaseManager databaseName: 'orcl') connect.
connection := AbtDbmSystem activeDatabaseConnection.
table := (connection openTableNamed: 'sql_table').
oc := OrderedCollection new.
1 to: 2 do: [ :n |
   newRow := table emptyRow.
   newRow
      at: #ID put: n;
      at: #LAST_NAME put: 'SMITH', n asString;
      at: #START_DATE put: Date today.
   oc add: newRow ].
connection autoCommit: true.
table addRows: oc


. . . a LOB script is as follows:

Code: Select all

"Insert an empty blob in a table"
| connection table oc clob newRow |
(AbtDatabaseConnectionSpec forDbmClass: AbtOracle10DatabaseManager databaseName: 'orcl') connect.
connection := AbtDbmSystem activeDatabaseConnection.
connection autoCommit: true.
table := (connection openTableNamed: 'clob_table').
clob := AbtOracleEmptyClob new.
oc := OrderedCollection new.
newRow := table emptyRow.
newRow
   at: #ID put: 5;
   at: #DATA put: clob.
oc add: newRow.
table addRows: oc.


. . . an empty LOB must first be inserted (above) then the data is inserted:

Code: Select all

| result fromFile querySpec resultCollection sqlString dict connection lobLocator buffer |
"get locator address"
(AbtDatabaseConnectionSpec forDbmClass: AbtOracle10DatabaseManager databaseName: 'orcl') connect.
connection := AbtDbmSystem activeDatabaseConnection.
sqlString :=  'select * from clob_table where id = 5 for update'.
querySpec := (AbtQuerySpec new) statement: sqlString.
resultCollection := OrderedCollection new.
result := connection resultTableFromQuerySpec: querySpec.
result do: [:eachRow | resultCollection add: eachRow asDictionary ].
dict := resultCollection first.
lobLocator := (dict at: 'DATA') locatorAddress.

buffer := 'Hello World!  Hello World! Hello World!  Hello World! Hello World!  Hello World! Hello World!  Hello World! Hello World!  Hello World!' asByteArray.
AbtOracleLobBuffer new
   writeBufferToLob: lobLocator buffer: buffer connection: connection.
connection commitUnitOfWork


--tc