Application class>>#isBasedOn: performance improvement

[g.cotelli]

Hi,

I found that moving classes between applications can be slow when there is a lot of applications and a long dependency chain. I tracked it down to Application>>isBasedOn: that performs always a recursive send.

I have changed:

Code: Select all

isBasedOn: application
      "Return whether application is a prerequisite of the receiver."

   self prerequisites do: [:prereq |
      prereq == application ifTrue: [^true].
      (prereq isBasedOn: application) ifTrue: [^true]].
   ^false

with:

Code: Select all

isBasedOn: application

   ^self isBasedOn: application alreadySeen: IdentitySet new

and:

Code: Select all

isBasedOn: application alreadySeen: anApplicationSet

   (anApplicationSet includes: self)
      ifTrue: [^false]
      ifFalse: [
         "Return whether application is a prerequisite of the receiver."
         self prerequisites do: [:prereq |
            prereq == application ifTrue: [^true].
            (prereq isBasedOn: application alreadySeen: anApplicationSet) ifTrue: [^true].
            anApplicationSet add: prereq].
         ^false]

Would be goog if this change can be included in the base image. Please review it before.

Regards,
Gabriel

[wembley]

Case 47978 created and fixed. Here is a testcase:

Code: Select all

  | allApplications prereqCount |

  allApplications := Application allSubclasses.
  prereqCount := 0.

  [allApplications do: [ :anApp |
    allApplications do: [ :prereqApp |
      anApp prerequisites ifNotNil: [  "Handle bogus AbtHtmlMigrationAgent"
        (anApp isBasedOn: prereqApp)
          ifTrue: [ prereqCount := prereqCount +1] ] ] ] ]bench: '#isBasedOn: '.
  Transcript cr; show: 'prereqCount: '; show: prereqCount printString

In a fully loaded VA Smalltalk image running on my WinXP Test VMware, the before output is:

#isBasedOn: 13313
prereqCount: 15266

and the after output is:

#isBasedOn: 5532
prereqCount: 15266