Error in Image NLS Error (VA)

[gsharma84]

Hi,
I keep getting this error in my image: NLS Error (VA). Missing group named: 'GtTrlBlzMRI'. Check that your MPR files exist and are properly registered.
what could be the possible reason behind this & what are MPR files?

Please reply, it would be of gr8 help.
thanks

I'm using VA Smalltalk 7.5.2

[PhotonDemon]

Hi gsharma84,

Is the problem with your development image or a runtime image? If it is your development image, you probably have a problem with your install of VA Smalltalk. If it is a runtime image, you need to supply the NLS files (and some DLLs). The NLS files are used to translate string to different languages.

Below is some code you can run in a workspace that can tell you what files are needed by your program. I haven't used this in a while but I think it is still good.

Lou

Code: Select all

"
Determining required CAT and MPR files for a reduced runtime image
The following script can be run to determine the .cat and .mpr message files that are needed by a
reduced image at runtime.  It reads the spusage.es file produced by packaging, so you should run the
script right after your packaging run so that you have the correct spusage.es file available.  The
required runtime message files will be listed on the Transcript:

The basis of the code is from someone at IBM (I have lost track of who) that I believe put
it in the public domain.  I have modified it to make it a little easier to use.
"

   | spusageFile fileStream class classCollection appCollection catFiles mprFiles work work2 icxFileName prompter file outFile |

   classCollection := Set new.
   appCollection := Set new.
   catFiles := Set new.
   mprFiles := Set new.

   prompter := CwFileSelectionPrompter new.
   file := prompter
      accessType: XmOPEN;
      searchMask: 'spusage.es';
      prompt.

   file isNil ifTrue: [^nil].
   spusageFile := file asFileSpec.
   fileStream := spusageFile cfsStreamReadOnlyIfError: [:aCfsErr |
      (AbtMessagePrompter new)
         buttonType: XmOK;
         title: 'Error';
         messageString: aCfsErr printString;
         iconType: XmICONERROR;
         prompt.
   ].
   (fileStream skipToAll: 'Output statistics for: ')
   ifTrue: [icxFileName := (fileStream nextLine)].
   (fileStream skipToAll: '#     Size    #     Size    #     Size') ifTrue: [
      fileStream nextLine; nextLine.
      [fileStream atEnd] whileFalse: [
         (class := fileStream upTo: $ ) isEmpty
         ifTrue: [fileStream setToEnd]
         ifFalse: [
            classCollection add: (class asClass).
            fileStream nextLine
         ].
      ].
   ].
   fileStream close.

   classCollection do: [:eachClass | | app |
      app := eachClass controller.
      appCollection add: app rootApplication].
      appCollection do: [:eachApp | | poolNames mprName |
         poolNames := eachApp definedPoolNames.
         poolNames do: [ :eachPoolName| | pool catName |
            (pool := (Smalltalk at: eachPoolName ifAbsent:[])) epIsPoolDictionary
            ifTrue:[(catName := (pool at: '!CATALOGNAME' ifAbsent: [])) isNil
            ifFalse: [catFiles add: (catName,'.cat')]]].
      (mprName := eachApp abtNlsRawFilename) isEmpty
         ifFalse: [mprFiles add: (AbtNLSCoordinator resolveLanguageMappingCharacter: mprName)]].

   work := ReadWriteStream on: (Locale current preferredStringClass new).
   work2 := ReadWriteStream on: (Locale current preferredStringClass new).
   work cr;
   nextPutAll: '******* There are ';
   nextPutAll: (catFiles size + mprFiles size) printString;
   nextPutAll: ' required message files for ';
   nextPutAll: icxFileName;
   nextPutAll: ' *******';
   cr;
   cr;
   nextPutAll: catFiles size printString;
   nextPutAll: ' Cat files:';
   cr.
   catFiles isEmpty
   ifTrue: [work tab; nextPutAll: 'No .cat files needed']
   ifFalse: [
      catFiles asSortedCollection doWithIndex: [:each :index |
         work tab; nextPutAll: each; cr.
         work2 nextPut: $"; nextPutAll: each; nextPutAll: '" '.
         ((index \\ 15) = 0) ifTrue: [work2 cr.].
      ].
      work2 cr.
   ].

   work cr;
   nextPutAll: mprFiles size printString;
   nextPutAll: ' Mpr files:'; cr.
   mprFiles isEmpty
   ifTrue: [work tab; nextPutAll: 'No .mpr files needed']
   ifFalse: [
      mprFiles asSortedCollection doWithIndex: [:each :index |
         work tab; nextPutAll: each; cr.
         work2 nextPut: $"; nextPutAll: each; nextPutAll: '" '.
         ((index \\ 15) = 0) ifTrue: [work2 cr.].
      ].
   ].
   work cr; nextPutAll: 'Clip these lines for use with InstallShield:'; cr; cr; nextPutAll: work2 contents; cr; cr.

   outFile := (((file copyFrom: 1 to: (file findLast: [:c | c = $\])), 'NeededFilesNLS.Txt') asFileSpec) cfsStreamCreateIfError:  [:aCfsErr |
      (AbtMessagePrompter new)
         buttonType: XmOK;
         title: 'Error';
         messageString: aCfsErr printString;
         iconType: XmICONERROR;
         prompt.
   ].
   Transcript bringToFront; nextPutAll: work contents.
   outFile nextPutAll: work contents; close.


[marten]

Hi,
I keep getting this error in my image: NLS Error (VA). Missing group named: 'GtTrlBlzMRI'. Check that your MPR files exist and are properly registered.
what could be the possible reason behind this & what are MPR files?

Please reply, it would be of gr8 help.
thanks

I'm using VA Smalltalk 7.5.2

mpr-files: binary files, with text (strings) stored for the GUI. You may need them for NLS purposes.

The "GtTrlBlzMRI" is used when loading the Tailblazer-browser. They should be stored within the subdirectory "nls" of your VASmalltalk installation directory and there you may look for a file "abttb?40.mpr", where "?" is a letter. You may therefore find "abttbe40.mpr" - for english text.

[gsharma84]

thanks,
I'm using a development image and I keep getting this error.
I have to reload a new image to get rid of this error.
I'm not sure as to what is causing this error. Lately I have been working on a lot of GUI stuff, Window Builder Pro, seems to me something in the GUI is causing the problem.